level.cfdg
2008-10-17 22:31:39
startshape level
rule level {
terminus {x -0.5 f 90 hue 20 y 1}
seg {}
weather{}
}
rule terminus {
CIRCLE{s 2 5.5 b 1 sat 0.5 x 0.2 r 3}
CIRCLE{s 2 5.5 b 1 sat 1 r 1}
CIRCLE{s 2 5 x 0.1 a -0.8 r -2}
CIRCLE{s 1.75 4.75 x 0.1}
}
rule avatar {
CIRCLE { s 1.5 b 1 sat 0.1 hue 220 y 0.9}
CIRCLE { s 1.5 b 0.1 sat 0.5 hue 220 y 0.8}
CIRCLE { s 1.5 b 0.5 sat 0.9 hue 220 y 0.85}
CIRCLE { s 1.25 b 1 sat 0.8 hue 220 y 0.85}
CIRCLE { s 0.25 b 1 y 1.15 x 0.25 a -0.2}
}
rule weather {
dub {y 2}
maybe_cloud {y 5}
}
rule dub {
CIRCLE {y +0.25 s 20 sat 0.1 b 1 hue 220 z -120}
CIRCLE {y -0.25 s 20 sat 0.3 b 1 hue 220 z -120}
CIRCLE {y 0 s 20 sat 0.2 b 1 hue 220 z -100}
}
rule maybe_cloud { maybe_cloud {f 90} }
rule maybe_cloud { maybe_cloud {x 2} }
rule maybe_cloud { maybe_cloud {y 0.2 } }
rule maybe_cloud {
CIRCLE {s 5 2 sat 0 b 1 y 0.1 hue 220 z -50}
CIRCLE {s 5 2 sat 0 b 0.8 y -0.1 hue 220 z -50}
CIRCLE {s 5 2 sat 0.1 b 1 hue 220 z -50}
}
rule maybe_cloud 0.5 {}
rule moar 10 {
seg{z 1}
weather{}
maybe_avatar{z 1}
}
rule moar {
terminus {hue 200 x -0.5 y 1}
weather{}
}
rule maybe_avatar { avatar {} }
rule maybe_avatar 2 { maybe_avatar {y 0.25} }
rule maybe_avatar { maybe_avatar {x -1} }
rule maybe_avatar 2 { maybe_avatar {hue 90} }
rule maybe_avatar 5 {}
rule seg { flat {} }
rule seg 0.5 { loop {} }
rule seg { gap {} }
rule seg { ramp {} }
rule seg { shift {} }
rule seg { round {x -0.25} }
rule round { round_down {} }
rule round { round_up {} }
rule shift { drop {} }
rule shift { hop {} }
rule ramp { ramp_up{} }
rule ramp { ramp_down{} }
rule round_up {
9*{x 0.5 r 10} thin{x 0.25}
3*{x 1} thick {x 4 y 3}
moar {x 7 y 3}
}
rule round_down {
9*{x 0.5 r -10} thin{x 0.25}
3*{x 1} thick {x 4 y -3}
moar {x 7 y -3}
}
rule loop {
36*{x 0.5 r 10} thin{x 0.25}
flat{z 1}
}
rule flat {
5*{x 1} thick{}
moar{x 5}
}
rule gap {
1*{x 1} thin{}
1*{x 1} thin{x 3}
moar{x 5}
}
rule drop {
1*{x 1} thick{}
1*{x 1} thin{x 3 y -3}
moar{x 5 y -3}
}
rule hop{
3*{x 1} thin{}
spring{x 0}
2*{x 1} thick{x 3 y 3}
moar{x 5 y 3}
}
rule ramp_up {
4*{x 1 y 0.25} thick{}
moar{y 1 x 4}
}
rule ramp_down {
4*{x 1 y -0.25} thick{}
moar{y -1 x 4}
}
rule spring {
SQUARE {s 0.85 0.20 b 1 sat 0.2 y 0.35}
SQUARE {s 0.85 0.25 y 0.25}
SQUARE {s 0.75 0.20 b 1 sat 1 y 0.30}
}
rule ground {
SQUARE {b 0.0 s 2 1 x +1 y -0.2 z -1 }
SQUARE {b 0.2 s 2 1 x +1 y -0.1 }
SQUARE {b 0.3 s 2 1 x +1 }
TRIANGLE {r 180 b 0.5 s 0.2 1 x 1.5}
}
rule blade {
TRIANGLE {s 0.2 1 y -0.1 b 1 sat 0.1}
TRIANGLE {s 0.2 2 y +0.25 b 1 sat 1 b 0.5}
TRIANGLE {s 0.2 1 z 1 b 1 sat 0.8 b 0.8}
}
rule grass {
11*{x 0.2} blade {r 180 y -0.25}
}
rule thick {
grass {s 0.5 hue 120 x -0.5}
6*{y -0.5 b 0.1} ground {s 0.5 hue 20 sat 0 b 0.3 x -0.5 y -0.5}
}
rule thin {
grass {s 0.5 hue 120 x -0.5}
2*{y -0.5 b 0.1} ground {s 0.5 hue 20 sat 0 b 0.3 x -0.5 y -0.5}
}
